Rumus INDEX MATCH Excel , Rumus Alternatif Pengganti VLOOKUP

Cara menggunakan rumus gabungan Index-Match Excel sebagai alternatif fungsi Vlookup pada microsoft excel yang tidak bisa menoleh ke kiri.

Gabungan fungsi INDEX-MATCH Excel merupakan alternatif rumus mencocokan data di excel yang sangat berguna untuk menggantikan fungsi atau rumus Vlookup.

Saat membandingkan data di excel dengan Vlookup, fungsi Vlookup tidak bisa mengambil data disebelah kiri. Sederhananya Vlookup tidak bisa menoleh ke sebelah kiri data yang dicari.

Sebelum menggunakan fungsi gabungan rumus excel INDEX dan MATCH ini tentunya harus menguasai dulu cara menggunakan kedua fungsi ini. Pada tutorial ini saya tidak akan membahas secara mendetail masing-masing fungsi excel tersebut, sebab sudah kami bahas pada halaman lain.

**File contoh bisa anda download pada akhir artikel

Meskpipun tidak secara detail saya kira penting juga untuk sedikit membahas kedua fungsi Index-Match ini terlebih dahulu, sekedar untuk mengingatkan dan mempermudah pembahasana saja.

Fungsi INDEX Pada Excel

Pada rumus excel, fungsi Index digunakan untuk mendapatkan data dari sebuah range atau array data sesuai dengan informasi kolom dan baris yang diberikan.

Cara penulisan rumus Index adalah sebagai berikut:

INDEX(Array; NomorBaris; [NomorKolom])

Nomor Kolom pada rumus index bisa diabaikan atau tidak diisi sesuai kebutuhan. Contoh rumus index pada gambar berikut:

Pada sel E5 index menghasilkan data baris ke-3 dari range A2:A8. Sedangkan pada sel E6, Formula Index menghasilkan data baris ke-3 dan kolom ke-2 dari range A2:B8.

Pembahasan lebih detail tentang fungsi Index bisa anda pelajari pada halaman berikut: Cara Menggunakan Fungsi INDEX Excel

Fungsi MATCH Pada Excel

Pada rumus excel, fungsi MATCH digunakan untuk mendapatkan posisi index atau posisi relatif data yang dicari pada range data pencarian.

Cara penggunaan Rumus Match adalah sebagai berikut:

MATCH(DatadiCari; RangePencarian; [TipePencarian])

Tipe pencarian pada fungsi MATCH boleh dikosongkan. Hanya saja umumnya diisi dengan nol "0" atau FALSE agar MATCH mencari data yang benar-benar sama persis. Perhatikan contoh berikut:

Pada gambar tersebut fungsi MATCH mencari posisi relatif dari "Nama 4" pada range A2:A8 hasilnya adalah 4.

Pembahasan lebih detail tentang fungsi Match bisa anda baca pada halaman berikut: Cara Menggunakan Fungsi MATCH Excel

Cara Menggunakan Rumus INDEX-MATCH Excel

Pada rumus gabungan INDEX-MATCH, fungsi MATCH digunakan untuk mengisi argumen atau bagian NomorBaris dan atau [NomorKolom] pada fungsi INDEX. Sehingga sintaks rumus indexnya menjadi:

Fungsi MATCH menggantikan argumen NomorBaris pada fungsi INDEX

INDEX(Array; MATCH(DatadiCari; RangePencarian; [TipePencarian]))

Fungsi MATCH menggantikan argumen NomorKolom pada fungsi INDEX
```
INDEX(Array; 1; MATCH(DatadiCari; RangePencarian; [TipePencarian]))
```
Pada sintaks diatas nomor baris diisi dengan angka 1, sebab nomor baris tidak boleh dikosongkan. Jika MATCH digunakan untuk mengisi nomor kolom maka nomor baris bisa diisi dengan angka 1.

Fungsi MATCH menggantikan argumen NomorBaris dan NomorKolom pada fungsi INDEX

INDEX(Array; MATCH(DatadiCari; RangePencarian; [TipePencarian]); MATCH(DatadiCari; RangePencarian; [TipePencarian]))

Untuk menggunakan rumus Index-Match dengan banyak kriteria bisa anda baca tutorialnya pada halaman berikut: Cara Lookup Banyak Kriteria Menggunakan Rumus Index-Match.

Untuk lebih jelaskan perhatikan contoh-contoh cara menggunakan rumus gabungan Index-Match berikut:

Contoh Rumus INDEX-MATCH Excel

Berikut beberapa contoh dalam menggunakan rumus Index dan Match pada microsoft excel

Index-Match Sebagai Alternatif Vlookup

Rumus Index-Match menggantikan fungsi Vlookup Excel

Untuk mencari alamat berdasarkan informasi Nama kita bisa menggunakan rumus VLookUp:

=VLOOKUP(C10;B2:D8;3;0)

Rumus Vlookup diatas bisa juga diganti dengan rumus index-match berikut:

=INDEX(D2:D8;MATCH(C10;B2:B8;0))

Rumus diatas mencari posisi Nama 6 pada range B2:B8 dengan fungsi MATCH. Hasilnya adalah 6. Posisi relatif 6 ini oleh fungsi Index dipakai sebagai informasi untuk menunjukkan nomor baris dari index data pada range D2:D8.

Index-Match Untuk VLookup Data ke Kiri

Rumus Index-Match menggantikan fungsi Vlookup Excel Menoleh ke Kiri

Pada contoh diatas, bermaksud mencari NAMA berdasarkan informasi NIS. Hal ini tidak bisa kita selesaikan dengan VlookUp biasa. Salah satu kelemahan fungsi VLOOKUP adalah tidak bisa mengambil data di kiri kolom pencarian. Hal ini bisa diatasi dengan menggunakan rumus Index-Match ini.

Rumus index-match pada sel C11 adalah:

=INDEX(B2:B8;MATCH(C10;C2:C8;0))

Index-Match Untuk Untuk Pencarian Berdasarkan Kolom dan Baris

Index-Match Pencarian Berdasar Kolom dan Baris.png

Pada contoh di atas dimaksudkan untuk mencari nilai angka penjualan pada range C2:E7 berdasarkan informasi ID dan Tahun. Rumus excel pada sel B11 yang digunakan pada contoh diatas adalah:

=INDEX(C2:E7;MATCH(B9;A2:A7;0);MATCH(B10;C1:E1;0))

Pada rumus diatas, nomor baris dicari dengan menggunakan rumus excel:

MATCH(B9;A2:A7;0)

Sedangkan nomor kolomnya menggunakan rumus excel:

MATCH(B10;C1:E1;0)

Keuntungan Menggunakan Rumus INDEX-MATCH Pada Microsoft Excel

Kenapa kita harus menggunakan rumus gabungan Index dan Match?

Kelebihan atau keuntungan yang bisa Anda dapat dengan menggunakan formula gabungan Index-Match ini antara lain:

Index-Match bisa menggantikan fungsi LOOKUP, HLOOKUP dan VLOOKUP. Jadi anda tidak perlu pusing-pusing memilih-milih fungsi mana yg cocok dipakai.
Bisa melakukan pencarian ke kiri/menoleh ke kiri yang tidak bisa dilakukan oleh vlookup. dengan index-match arah pencarian menjadi lebih fleksibel.
Bisa melakukan insert kolom dengan aman. Jika memakai Vlookup maka kita perlu menyesuaikan lagi nomor kolomnya.
Untuk data yang relatif besar, formula Index-Match ini relatif lebih cepat jika dibandingkan dengan fungsi LOOKUP, HLOOKUP maupun VLOOKUP.
Fungsi MATCH bisa melakukan pencarian data dengan menggunakan Whilchard karakter, sehingga proses pencarian menjadi lebih dinamis.
Index-match bisa juga digunakan dengan fungsi-fungsi lain yang lebih kompleks. Misal untuk menyelesaikan kasus VlookUp 2 Kriteria atau lebih.

Download File Latihan Rumus INDEX-MATCH

Sebagai pelengkap silahkan download contoh file untuk artikel ini dibawah ini:

Download File *Jika link mati / tidak dapat diakses silahkan lapor via kontak yang tersedia

Jika masih kurang jelas atau punya masalah sejenis silahkan sampaikan di kolom komentar.

Berikut beberapa tutorial excel lain tentang Rumus VLookup yang bisa anda pelajari: