Rumus Excel Menghitung Jumlah Kata atau Teks

Rumus Excel Menghitung Jumlah Kata atau Teks

Rumus menghitung jumlah kata atau jumlah teks tertentu pada kalimat sebuah sel atau range excel.
Rumus Excel Menghitung Jumlah Kata atau Teks

Rumus Menghitung Jumlah Kata - Untuk mengetahui jumlah karakter atau huruf pada sebuah sel excel, kita bisa menggunakan fungsi Len yang sudah di bahas pada tutorial excel yang lalu.

Lalu bagaimana cara menghitung jumlah kata pada sebuah sel atau range excel?

Meskipun excel tidak menyediakan fungsi khusus untuk menghitung kata (count word), bukan berarti excel tidak bisa melakukan hal ini.

Kelas excel kali ini akan membahas rumus-rumus excel yang bisa kita gunakan untuk memecahkan kasus ini.

Untuk lebih jelasnya mari kita bahas masalah ini satu persatu.

Istilah kata yang dimaksud pada pembahasan ini adalah sekumpulan huruf atau karakter teks yang dipisahkan oleh spasi.

Menghitung Jumlah Total Kata Sebuah Cell

Untuk menghitung jumlah kata dalam kalimat sebuah sel pada microsoft excel kita bisa menggunakan rumus excel berikut:

=LEN(Kalimat)-LEN(SUBSTITUTE(Kalimat;" ";""))+1

Kalimat pada rumus diatas merupakan teks atau referensi sel yang akan kita hitung jumlah total katanya. Contoh penerapannya adalah sebagai berikut:

Cara menghitung jumlah kata sebuah sel excel

Pada sel B2 di atas rumus yang digunakan adalah:

=LEN(A2)-LEN(SUBSTITUTE(A2;" ";""))+1

LEN(A2) dimaksudkan untuk menghitung jumlah keseluruhan karakter pada sel A2. Sedangkan LEN(SUBSTITUTE(A2;" ";"")) digunakan untuk menghitung jumlah karakter teks tersebut tanpa menghitung spasi.

Agar dapat menghitung jumlah karakter tanpa spasi maka spasi perlu kita hilangkan terlebih dahulu yakni dengan menggunakan fungsi SUBSTITUTE seperti di atas.

Jika pada kalimat yang akan kita hitung jumlah total kata-nya terdapat spasi ganda rumus di atas akan menghasilkan nilai yang tidak tepat. untuk itu spasi ganda harus kita hilangkan terlebih dahulu dari teks ini. Caranya adalah dengan menggunakan fungsi TRIM, sehingga rumus excelnya akan menjadi sepeti di bawah ini:

=LEN(TRIM(A2))-LEN(SUBSTITUTE(A2;" ";""))+1

Tentang cara menghilangkan spasi ganda ini ada pembahasan tersendiri yang bisa anda temukan pada tutorial berikut:

Cara Menghapus Spasi Ganda atau Berlebih di Excel

Tanpa menghitung jumlah kata per sel, bisakah kita menghitung jumlah keseluruhan kata pada sebuah range excel? mari lanjut ke pembahasan berikutnya.

Menghitung Jumlah Total Kata Pada Sebuah Range

Jika pada rumus excel sebelumnya hanya menghitung kata dari sebuah sel, maka bagaimana cara untuk menghitung jumlah keseluruhan kata dari sebuah range?

Selain menghitung sel satu persatu lalu menjumlahkan hasilnya misalnya dengan fungsi SUM untuk mengetahui jumlah keseluruhan kata pada sel, kita bisa juga menghitung total kata pada sebuah range secara langsung dengan menggunakan sebuah array formula.

Apa itu array formula sudah kita bahas sebelumnya. Jika belum membacanya silahkan menuju laman berikut terlebih dahulu:

Array formula pada microsoft excel

Rumus array yang dimaksud adalah sebagai berikut:

=SUM(LEN(RangeKalimat)-LEN(SUBSTITUTE(RangeKalimat;" ";""))+1)

Setelah menuliskan rumus di atas akhiri dengan menekan tombol Ctrl + Shift + Enter secara bersama-sama.

Perhatikan contoh berikut:

Cara menghitung jumlah kata sebuah range excel

Rumus excel pada sel B8 di atas adalah:

{=SUM(LEN(A2:A4)-LEN(SUBSTITUTE(A2:A4;" ";""))+1)}

Tanda {...} tidak kita tulis manual, melainkan otomatis muncul sebagai penunjuk bahwa rumus tersebut merupakan rumus Array yang kita inputkan dengan cara menekan CSE Ctrl + Shift + Enter secara bersama-sama.

Selain menggunakan rumus array seperti di atas kita juga bisa menggunakan formula excel biasa yakni dengan memanfaatkan fungsi Sumproduct berikut:

=SUMPRODUCT(LEN(RangeKalimat)-LEN(SUBSTITUTE(RangeKalimat;" ";""))+1)

Jika diterapkan pada contoh di atas rumus excelnya akan menjadi seperti pada sel B9 contoh di atas:

=SUMPRODUCT(LEN(A2:A4)-LEN(SUBSTITUTE(A2:A4;" ";""))+1)

Selain menggunakan rumus pada bagian sebelumnya, untuk sel tunggal bisa juga kita hitung jumlah katanya dengan kedua rumus yang dijelaskan pada bagian ini.

Setelah mempelajari kedua rumus di atas biasanya akan muncul pertanyaan "Bagaimana jika kita hanya menghendaki menghitung jumlah kata tertentu saja?"

Menghitung Jumlah Kata Tertentu Pada Sebuah Cell Excel

Selain menghitung jumlah total keseluruhan kata dalam sebuah kalimat di excel, kita juga bisa menghitung jumlah kata atau teks tertentu saja.

Caranya adalah dengan menggunakan rumus excel berikut:

=SUM(LEN(AlamatSel)-LEN(SUBSTITUTE(AlamatSel;"TeksDihitung","")))/LEN("TeksDihitung")

Misalnya untuk menghitung jumlah kata "excel" pada sel A2 rumus yang digunakan adalah:

=SUM(LEN(A2)-LEN(SUBSTITUTE(A2;"excel";"")))/LEN(A5)
Cara menghitung jumlah teks tertentu pada sebuah sel excel

Perlu diketahui bahwa fungsi Subtitute bersifat case sensitive(huruf besar dan kecil dianggap berbeda), sehingga kata "excel" dan "Excel" akan dianggap berbeda.

Jika anda ingin menghitung jumlah kata tanpa membedakan besar kecilnya huruf maka teks dalam sel yang akan kita hitung perlu kita rubah ke huruf besar semua atau menjadi huruf kecil semua dengan fungsi UPPER atau LOWER.

Rumus di atas jika gunakan untuk menghitung jumlah kata tertentu tanpa membedakan besar kecilnya huruf menjadi seperti berikut:

Cara menghitung jumlah teks tertentu non case-sensitive
=SUM(LEN(A2)-LEN(SUBSTITUTE(UPPER(A2);UPPER(A5);"")))/LEN(A5)

atau

=SUM(LEN(A2)-LEN(SUBSTITUTE(LOWER(A2);LOWER(A5);"")))/LEN(A5)

Bagaimana untuk menghitung teks tertentu pada sebuah range?

Menghitung Jumlah Kata Tertentu Pada Sebuah Range Excel

Selain digunakan untuk menghitung jumlah teks atau kata tertentu pada sebuah sel rumus diatas bisa juga diterapkan untuk sebuah range. Hanya saja rumus ini diperlakukan sebagai rumus array yang harus di akhiri dengan Ctrl + Shift + Enter.

{=SUM(LEN(A2:A4)-LEN(SUBSTITUTE(A2:A4;"excel";"")))/LEN("excel")}

Jika tidak menghendaki menggunakan array formula, gunakan fungsi Sumproduct untuk menggantikan fungsi SUM pada rumus di atas.

=SUMPRODUCT(LEN(A2:A4)-LEN(SUBSTITUTE(A2:A4;"excel";"")))/LEN("excel")
Cara menghitung jumlah teks tertentu pada sebuah range excel

Seperti sebelumnya jika ingin mengabaikan huruf besar dan kecil maka gunakan fungsi LOWER atau UPPER pada kedua rumus di atas.

{=SUM(LEN(A2:A4)-LEN(SUBSTITUTE(LOWER(A2:A4);LOWER("Excel");"")))/LEN("Excel")}

 

=SUMPRODUCT(LEN(A2:A4)-LEN(SUBSTITUTE(LOWER(A2:A4);LOWER("Excel");"")))/LEN("Excel")
Cara menghitung jumlah teks non case-sensitive range excel

Rumus-rumus di atas digunakan untuk menghitung teks/kata tertentu pada sel dan range excel. Lalu bagaimana cara menghitung banyaknya sel yang mengandung teks tertentu?

Pertanyaan ini akan kita jawab pada tutorial excel berikutnya.

Cara Menghitung Jumlah Data Yang Mengandung Teks Tertentu Pada Microsoft Excel

Silahkan subscribe atau berlangganan artikel tutorial excel agar segera mendapatkan pemberitahuan setiap ada artikel baru dari blog ini. Jangan lupa juga Join akun media sosial resmi kami.

LANGGANAN GRATIS!

Dapatkan update tutorial excel gratis langsung ke email anda.