Rumus Terbilang Excel Manual Tanpa Macro Untuk Merubah Angka Menjadi Huruf

Rumus Terbilang Excel Manual Tanpa Macro Untuk Merubah Angka Menjadi Huruf

Rumus Terbilang Excel Untuk Merubah Angka Menjadi Huruf

Merubah angka menjadi huruf atau kalimat secara otomatis seringkali kita butuhkan saat bekerja dengan microsoft excel. Kasus seperti ini biasanya disebut dengan fungsi atau rumus terbilang excel.

Hal ini mengacu pada pembuatan kwitansi yang biasanya menyebut kalimat terbilang dari nominal rupiah. Misalnya merubah angka Rp. 750.000,- menjadi Tujuhratus Limapuluh Ribu Rupiah.

Umumnya cara yang ditawarkan dalam kasus terbilang excel ini menggunakan kode macro VBA atau menggunakan ADDIN terbilang excel.


Menggunakan kode VBA atau Addin fungsi terbilang rupiah pada excel ternyata memiliki beberapa kekurangan, antara lain:

  1. Jika menggunakan addin, kemungkinan fungsi terbilang tidak akan bekerja jika dibuka pada komputer lain.
  2. Jika menggunakan kode VBA bagi yang awam akan kesulitan menerapkannya.
  3. Jika menggunakan kode VBA maka file tidak bisa disimpan dengan ekstensi .xlsx
  4. Dan lain-lain.

Sebenarnya selain menggunakan kode VBA dan atau Addin terbilang rupiah excel kita bisa menggunakan kombinasi beberapa fungsi excel untuk membuat rumus terbilang excel.

Kali ini saya akan berbagi dua macam rumus terbilang excel. Yang pertama untuk terbilang rupiah misalnya angka 1.500.000 menjadi Satu Juta Lima Ratus Ribu. Yang kedua rumus terbilang excel untuk merubah angka ke kata misal 89,90 menjadi Delapan Sembilan Koma Sembilan Nol

RUMUS TERBILANG EXCEL RUPIAH


Rumus Terbilang Excel Rupiah

Dalam kasus ini rumus excel kita gunakan untuk merubah angka menjadi kalimat seperti ejaan bahasa Indonesia pada umumnya. Rumus terbilang excelnya adalah:

=IF(A1=0;"nol";IF(A1<0;"minus ";"")&
SUBSTITUTE(TRIM(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(
IF(--MID(TEXT(ABS(A1);"000000000000000");1;3)=0;"";MID(TEXT(ABS(A1);"000000000000000");1;1)&" ratus "&MID(TEXT(ABS(A1);"000000000000000");2;1)&" puluh "&MID(TEXT(ABS(A1);"000000000000000");3;1)&" trilyun ")&
IF(--MID(TEXT(ABS(A1);"000000000000000");4;3)=0;"";MID(TEXT(ABS(A1);"000000000000000");4;1)&" ratus "&MID(TEXT(ABS(A1);"000000000000000");5;1)&" puluh "&MID(TEXT(ABS(A1);"000000000000000");6;1)&" milyar ")&
IF(--MID(TEXT(ABS(A1);"000000000000000");7;3)=0;"";MID(TEXT(ABS(A1);"000000000000000");7;1)&" ratus "&MID(TEXT(ABS(A1);"000000000000000");8;1)&" puluh "&MID(TEXT(ABS(A1);"000000000000000");9;1)&" juta ")&
IF(--MID(TEXT(ABS(A1);"000000000000000");10;3)=0;"";IF(--MID(TEXT(ABS(A1);"000000000000000");10;3)=1;"*";MID(TEXT(ABS(A1);"000000000000000");10;1)&" ratus "&MID(TEXT(ABS(A1);"000000000000000");11;1)&" puluh ")&MID(TEXT(ABS(A1);"000000000000000");12;1)&" ribu ")&
IF(--MID(TEXT(ABS(A1);"000000000000000");13;3)=0;"";MID(TEXT(ABS(A1);"000000000000000");13;1)&" ratus "&MID(TEXT(ABS(A1);"000000000000000");14;1)&" puluh "&MID(TEXT(ABS(A1);"000000000000000");15;1));1;"satu");2;"dua");3;"tiga");4;"empat");5;"lima");6;"enam");7;"tujuh");8;"delapan");9;"sembilan");"0 ratus";"");"0 puluh";"");"satu puluh 0";"sepuluh");"satu puluh satu";"sebelas");"satu puluh dua";"duabelas");"satu puluh tiga";"tigabelas");"satu puluh empat";"empatbelas");"satu puluh lima";"limabelas");"satu puluh enam";"enambelas");"satu puluh tujuh";"tujuhbelas");"satu puluh delapan";"delapanbelas");"satu puluh sembilan";"sembilanbelas");"satu ratus";"seratus");"*satu ribu";"seribu");0;""));"  ";" "))

Kog rumus excelnya panjang banget? ahahahahahaa... Meskipun panjang kan tinggal copy paste saja.

Pada rumus diatas referensi sel A1 merupakan angka yang aakan dirubah menjadi teks/huruf terbilang.

Untuk menambahkan kalimat rupiah tambahkan rumus excel berikut di akhir rumus terbilang excel diatas.

&" Rupiah"

Sehingga rumus terbilang excelnya menjadi:

=IF(A1=0;"nol";IF(A1<0;"minus ";"")&
SUBSTITUTE(TRIM(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(
IF(--MID(TEXT(ABS(A1);"000000000000000");1;3)=0;"";MID(TEXT(ABS(A1);"000000000000000");1;1)&" ratus "&MID(TEXT(ABS(A1);"000000000000000");2;1)&" puluh "&MID(TEXT(ABS(A1);"000000000000000");3;1)&" trilyun ")&
IF(--MID(TEXT(ABS(A1);"000000000000000");4;3)=0;"";MID(TEXT(ABS(A1);"000000000000000");4;1)&" ratus "&MID(TEXT(ABS(A1);"000000000000000");5;1)&" puluh "&MID(TEXT(ABS(A1);"000000000000000");6;1)&" milyar ")&
IF(--MID(TEXT(ABS(A1);"000000000000000");7;3)=0;"";MID(TEXT(ABS(A1);"000000000000000");7;1)&" ratus "&MID(TEXT(ABS(A1);"000000000000000");8;1)&" puluh "&MID(TEXT(ABS(A1);"000000000000000");9;1)&" juta ")&
IF(--MID(TEXT(ABS(A1);"000000000000000");10;3)=0;"";IF(--MID(TEXT(ABS(A1);"000000000000000");10;3)=1;"*";MID(TEXT(ABS(A1);"000000000000000");10;1)&" ratus "&MID(TEXT(ABS(A1);"000000000000000");11;1)&" puluh ")&MID(TEXT(ABS(A1);"000000000000000");12;1)&" ribu ")&
IF(--MID(TEXT(ABS(A1);"000000000000000");13;3)=0;"";MID(TEXT(ABS(A1);"000000000000000");13;1)&" ratus "&MID(TEXT(ABS(A1);"000000000000000");14;1)&" puluh "&MID(TEXT(ABS(A1);"000000000000000");15;1));1;"satu");2;"dua");3;"tiga");4;"empat");5;"lima");6;"enam");7;"tujuh");8;"delapan");9;"sembilan");"0 ratus";"");"0 puluh";"");"satu puluh 0";"sepuluh");"satu puluh satu";"sebelas");"satu puluh dua";"duabelas");"satu puluh tiga";"tigabelas");"satu puluh empat";"empatbelas");"satu puluh lima";"limabelas");"satu puluh enam";"enambelas");"satu puluh tujuh";"tujuhbelas");"satu puluh delapan";"delapanbelas");"satu puluh sembilan";"sembilanbelas");"satu ratus";"seratus");"*satu ribu";"seribu");0;""));"  ";" "))
&" Rupiah"

Anda bisa menggunakan fungsi-fungsi microsoft excel untuk merubah besar kecil huruf semisal fungsi PROPER. Jika digabung rumus terbilang excel diatas menjadi:

=PROPER(IF(A1=0;"nol";IF(A1<0;"minus ";"")&
SUBSTITUTE(TRIM(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(
IF(--MID(TEXT(ABS(A1);"000000000000000");1;3)=0;"";MID(TEXT(ABS(A1);"000000000000000");1;1)&" ratus "&MID(TEXT(ABS(A1);"000000000000000");2;1)&" puluh "&MID(TEXT(ABS(A1);"000000000000000");3;1)&" trilyun ")&
IF(--MID(TEXT(ABS(A1);"000000000000000");4;3)=0;"";MID(TEXT(ABS(A1);"000000000000000");4;1)&" ratus "&MID(TEXT(ABS(A1);"000000000000000");5;1)&" puluh "&MID(TEXT(ABS(A1);"000000000000000");6;1)&" milyar ")&
IF(--MID(TEXT(ABS(A1);"000000000000000");7;3)=0;"";MID(TEXT(ABS(A1);"000000000000000");7;1)&" ratus "&MID(TEXT(ABS(A1);"000000000000000");8;1)&" puluh "&MID(TEXT(ABS(A1);"000000000000000");9;1)&" juta ")&
IF(--MID(TEXT(ABS(A1);"000000000000000");10;3)=0;"";IF(--MID(TEXT(ABS(A1);"000000000000000");10;3)=1;"*";MID(TEXT(ABS(A1);"000000000000000");10;1)&" ratus "&MID(TEXT(ABS(A1);"000000000000000");11;1)&" puluh ")&MID(TEXT(ABS(A1);"000000000000000");12;1)&" ribu ")&
IF(--MID(TEXT(ABS(A1);"000000000000000");13;3)=0;"";MID(TEXT(ABS(A1);"000000000000000");13;1)&" ratus "&MID(TEXT(ABS(A1);"000000000000000");14;1)&" puluh "&MID(TEXT(ABS(A1);"000000000000000");15;1));1;"satu");2;"dua");3;"tiga");4;"empat");5;"lima");6;"enam");7;"tujuh");8;"delapan");9;"sembilan");"0 ratus";"");"0 puluh";"");"satu puluh 0";"sepuluh");"satu puluh satu";"sebelas");"satu puluh dua";"duabelas");"satu puluh tiga";"tigabelas");"satu puluh empat";"empatbelas");"satu puluh lima";"limabelas");"satu puluh enam";"enambelas");"satu puluh tujuh";"tujuhbelas");"satu puluh delapan";"delapanbelas");"satu puluh sembilan";"sembilanbelas");"satu ratus";"seratus");"*satu ribu";"seribu");0;""));"  ";" "))&" Rupiah")

Untuk menggunakan rumus terbilang excel diatas ada beberapa hal yang perlu diperhatikan.

  1. excel hanya menampilkan maksimal 15 digit angka. Jadi jika anda membutuhkan lebih dari 15 digit rumus diatas tidak akan menghasilkan fungsi terbilang sebagaimana mestinya.
  2. Rumus terbilang excel diatas tidak bisa menampung angka dibelakang koma, jika anda membutuhkan angka dibelakang koma jangan menggunakan rumus diatas atau pisahkan dulu antara angka depan koma dan belakang koma. Untuk kebutuhan ini silahkan baca tutorial tentang pembulatan excel.
  3. A1 pada rumus diatas adalah sel dimana angka yang akan kita konversi ke kalimat berada jadi silahkan disesuaikan.
  4. Jika regional setting komputer anda masih default english rubah ke bahasa Indonesia atau silahkan ganti Titik koma (;) pada rumus excel diatas menjadi koma (,). Untuk kebutuhan merubah karakter teks secara bersamaan silahkan baca artikel tentang fitur FIND and REPLACE.

Untuk penjelasan masing-masing fungsi yang digunakan silahkan baca artikel-artikel belajar excel sebelumnya: Fungsi SUBTITUTE, Fungsi MID, Fungsi TRIM

RUMUS TERBILANG EXCEL ANGKA KE KATA


Rumus Terbilang Excel Angka ke Huruf

Dalam kasus ini rumus terbilang excel kita gunakan untuk merubah angka ke huruf atau kata seperti merubah angka 87,70 menjadi "Delapan Tujuh Koma Tujuh Nol".

Rumus terbilang excel yang bisa kita gunakan adalah:
=SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(TEXT(A1;"#,00");
0;"Nol ");1;"Satu ");2;"Dua ");3;"Tiga ");4;"Empat ");5;"Lima ");6;"Enam ");7;"Tujuh ");8;"Delapan ");9;"Sembilan ");",";"Koma ")

A1 pada rumus excel diatas merupakan sel dimana angka yang akan kita rubah berada jadi silahkan sesuaikan dengan kebutuhan.

Jika hanya menghendaki satu angka dibelakang koma maka sesuaikan "#,00" menjadi "#,0" atau yang lainnya sesuai kebutuhan.

Untuk kebutuhan yang lain silahkan berekplorasi dengan trial dan error ehehehee... misalnya merubah nol dengan kosong, menggunakan fungsi UPPER, menambah kalimat rupiah dan lain sebagainya.

Jika anda kreatif anda juga bisa menggabungkan rumus terbilang excel rupiah dan rumus terbilang excel angka ke kata.

Khusus untuk angka 1-100 misal sekedar untuk konversi nilai ujian, sebaiknya tidak menggunakan rumus diatas. Namun gunakan fungsi Vlookup. Tutorialnya bisa anda pelajari pada tautan berikut:

Rumus Terbilang Manual Dengan Fungsi Vlookup Excel

Demikian semoga bermanfaat.

Untuk penggunaan lebih simple anda bisa menggunakan addin terbilang yang sudah saya bagikan sebelumnya.

0 komentar