Rumus Excel Untuk Menghilangkan Data Yang Sama dan Mengambil Data Unik

Rumus Excel Untuk Menghilangkan Data Yang Sama

Bagaimanakah rumus excel yang digunakan untuk menghilangkan data yang sama (ganda/double/duplikat) untuk mengambil atau mendapatkan list data uniknya?

Pada tutorial excel sebelumnya kita sudah mendiskusikan tentang cara untuk menghapus data ganda/duplikat. Teknik yang digunakan pada tutorial sebelumnya adalah menggunakan fitur remove duplicates serta menggunakan fitur advanced filter.

Tujuan utama dalam menghilangkan data yang sama atau ganda ini pada dasarnya adalah untuk memisahkan data yang sama atau mengelompokkan data yang sama sehingga didapatkan list atau daftar unik dari sekumpulan data yang kita miliki.

Selain menggunakan fitur excel sebenarnya kita juga bisa menggunakan rumus excel untuk mengambil data unik dari sekumpulan data yang mengandung duplikat. Cara ini biasanya digunakan untuk mengolah data yang dinamis atau berubah setiap saat.


A. RUMUS MENGAMBIL LIST UNIK TANPA BLANK CELL (SEL KOSONG)


Dengan rumus excel, cara menghilangkan data yang sama untuk mendapatkan list unik dari sekumpulan data yang memiliki duplikat adalah sebagai berikut:

Misal data yang akan kita ekstrak list uniknya adalah data pada range A2:A11 seperti pada contoh berikut. Kemudian hasil list uniknya (unique list) akan kita tempatkan mulai pada kolom C mulai sel C2.

Menghilangkan Data Yang Sama 1

Pada sel C2 tuliskan rumus excel berikut:

=IFERROR(INDEX($A$2:$A$11;MATCH(0;COUNTIF($C$1:C1;$A$2:$A$11);0));"")

Akhiri dengan Ctrl+Shift+Enter (Array Formula). Kemudian copy paste rumus ke sel lain dibawahnya.

Range $A$2:$A$11 merupakan range data yang mengandung duplikat yang akan kita ambil data uniknya.

Rumus diatas diperlakukan sebagai rumus Array sehingga setelah selesai menuliskan rumus excel diatas tekan CTRL+SHIFT+ENTER secara bersamaan, jangan hanya menekan Enter saja. Sehingga rumusnya akan tampak seperti di gambar (Diapit {...}).

Pada penulisan rumus diatas yang perlu diperhatikan adalah pengisian argumen Fungsi Countif:

COUNTIF($C$1:C1;$A$2:$A$11)

Pada pemakaian rumus countif tersebut argumen range menggunakan referensi semi absolut ($C$1:C1). sedangkan pada argumen kriteria menggunakan referensi sel absolut ($A$2:$A$11).

Penjelasan detail tentang fungsi/rumus countif bisa anda pelajari pada link berikut: Menghitung Banyak Data dengan Syarat Tertentu

Dengan rumus excel diatas jika terdapat sel kosong (Blank Cell) atau angka (Numbers) pada list data duplikat, maka sel ini tidak diabaikan. Sehingga hasil yang didapat akan seperti dibawah ini:

Menghilangkan Data Yang Sama 2

Untuk mengabaikan data yang mengandung sel kosong gunakan rumus excel untuk menghilangkan data yang sama berikutnya dibawah ini.

B. RUMUS MENGAMBIL LIST UNIK DAN MENGABAIKAN BLANK CELL (SEL KOSONG)


Jika list yang akan kita ambil nilai uniknya mengandung sel kosong dan kita ingin sel ini diabaikan saat pengambilan list unik dari data yang mengandung duplikat, maka rumus excel yang bisa digunakan adalah sebagai berikut:

=IFERROR(INDEX($A$2:$A$11;MATCH(0;COUNTIF($C$1:C1;$A$2:$A$11&"")+IF($A$2:$A$10="";1;0);0));"")

Akhiri dengan Ctrl+Shift+Enter (Array Formula), kemudian copy paste rumus ke sel lain dibawahnya.

Menghilangkan Data Yang Sama 3

Selain rumus excel diatas, alternatif rumus excel untuk mengambil list unik dari data yang mengandung blank cell adalah dengan menggunakan rumus excel berikut:

=IFERROR(INDEX($A$2:$A$11;MATCH(0;IF(ISBLANK($A$2:$A$11);1;COUNTIF($D$1:D1;$A$2:$A$11));0));"")

Akhiri dengan Ctrl+Shift+Enter (Array Formula).

Menghilangkan Data Yang Sama 4

Dengan menggunakan rumus array excel (Array formula) diatas hanya mengabaikan sel yang kosong saja. untuk mengabaikan sel kosong serta sel yang berisi angka gunakan rumus excel rumus excel untuk menghilangkan data yang sama berikutnya.

C. RUMUS MENGAMBIL LIST UNIK, MENGABAIKAN BLANK CELL (SEL KOSONG) DAN ANGKA (NUMBERS)


Jika bermaksud mengabaikan sel kosong (Blank Cells) dan Angka (Numbers) dalam mengambil list unik dari data yang mengandung duplikat, maka rumus excel yang bisa digunakan untuk menghilangkan data yang sama seperti di bawah ini:

=IFERROR(INDEX($A$2:$A$11;MATCH(0;COUNTIF($C$1:C1;$A$2:$A$11&"")+IF(ISTEXT($A$2:$A$10)=FALSE;1;0);0));"")

Akhiri dengan Ctrl+Shift+Enter (Array Formula), kemudian copy paste rumus ke sel lain dibawahnya.

Menghilangkan Data Yang Sama 5

Dengan menggunakan rumus excel diatas maka sel yang kosong serta sel yang bernilai angka tidak diikut sertakan dalam penyusunan list unik.

Selain menggunakan referensi absolut. referensi range $A$2:$A$11 bisa juga diganti dengan menamai range tersebut. Pembahasan tentang cara menamani range bisa anda pelajari pada link berikut: 3 Cara Memberi Nama Range Pada Excel.

File latihan untuk pembahasan kali ini bisa anda download melalaui link di bawah ini :

Download File

*Jika link mati / tidak dapat diakses silahkan lapor via kontak yang tersedia
Menu Download Terkunci.
Klik Bagikan (G+ atau Tweet) untuk membuka kunci/melihat Link Download


Demikian pembahasan kita kali ini tentang rumus excel untuk menghilangkan data yang sama untuk mendapatkan data unik dari sekumpulan data yang memiliki duplikat.

0 komentar